ab.com コミュニティ

何時も、お世話に成っています。

　実践コードモジュールで、Toshi様の「IE コンポーネントを表示してみる」
　(http://www.activebasic.com/forum/viewtopic.php?t=435)
を使わして頂いてますが、全選択（CTRL+Ａ）が出来ないのですが度の様に
すれば良いのでしょうか？

EM_SETSELを試しましたが駄目でした。
CreateWindowEx（）の戻り値がハンドルじゃ無いのでしょうか？

宜しくお願いします。

CreateWindowExの戻り値は確かにハンドルですが"AtlAxWin"という特殊なウィンドウクラスのため通常の方法では操作できません
おそらくはiwebbrowser2インターフェースからの操作する事になると思いますが、そちらの方は疎いので明確にはお答えできないです

あのコードですと、Ctrl+A に限らず多くのショートカットキーが効きません。
なのでいっそ IE コンポーネントにそのあたりの処理を任せるようにしてみます。
これで IE コンポーネントで有効なあらゆるショートカットキーが使えます。

まず必要な宣言を追加します。別なファイルとしてプロジェクトに追加するなどします。

[ここをクリックすると内容が表示されます]

コード: 全て選択

TypeDef HRESULT=Long
TypeDef BSTR=WordPtr

Interface IDispatch 
    Inherits IUnknown 

    Function GetTypeInfoCount(pctinfo As DWordPtr) As HRESULT 
    Function GetTypeInfo(iTInfo As DWord,lcid As DWord,ITypeInfo As VoidPtr) As HRESULT 
    Function GetIDsOfNames(riid As DWord,rgszNames As BytePtr,cNames As DWord,lcid As DWord,rgDispID As DWordPtr) As HRESULT 
    Function Invoke(dispIdMember As DWord,riid As DWord,lcid As DWord,wFlags As Word,pDispParams As DWordPtr,pVarResult As VoidPtr,pExcepInfo As DWordPtr,puArgErr As DWordPtr) As HRESULT 

End Interface 

Interface IWebBrowser 
    Inherits IDispatch 

    Function GoBack() As HRESULT 
    Function GoForward() As HRESULT 
    Function GoHome() As HRESULT 
    Function GoSearch() As HRESULT 
    Function Navigate(URL As BSTR,Flags As VoidPtr,TargetFrameName As VoidPtr,PostData As VoidPtr,Headers As VoidPtr) As HRESULT 
    Function Refresh() As HRESULT 
    Function Refresh2(Level As VoidPtr) As HRESULT 
    Function Stop() As HRESULT 
    Function get_Application(ppDisp As VoidPtr) As HRESULT 
    Function get_Parent(ppDisp As VoidPtr) As HRESULT 
    Function get_Container(ppDisp As VoidPtr) As HRESULT 
    Function get_Document(ppDisp As VoidPtr) As HRESULT 
    Function get_TopLevelContainer(pBool As VoidPtr) As HRESULT 
    Function get_Type(Type_ As *BSTR) As HRESULT 
    Function get_Left(pl As *Long) As HRESULT 
    Function put_Left(Left As Long) As HRESULT 
    Function get_Top(pl As *Long) As HRESULT 
    Function get_Top(Top As Long) As HRESULT 
    Function get_Width(pl As *Long) As HRESULT 
    Function get_Width(Width As Long) As HRESULT 
    Function get_Height(pl As *Long) As HRESULT 
    Function get_Height(Height As Long) As HRESULT 
    Function get_LocationName(LocationName As *BSTR) As HRESULT 
    Function get_LocationURL(LocationURL As *BSTR) As HRESULT 
    Function get_Busy() As HRESULT 

End Interface 

Interface IWebBrowserApp 
    Inherits IWebBrowser 

    Function Quit() As HRESULT 
    Function ClientToWindow() As HRESULT 
    Function PutProperty() As HRESULT 
    Function GetProperty() As HRESULT 
    Function get_Name() As HRESULT 
    Function get_HWND() As HRESULT 
    Function get_FullName() As HRESULT 
    Function get_Path() As HRESULT 
    Function get_Visible() As HRESULT 
    Function put_Visible(bBool As Long) As HRESULT 
    Function get_StatusBar() As HRESULT 
    Function put_StatusBar() As HRESULT 
    Function get_StatusText() As HRESULT 
    Function put_StatusText() As HRESULT 
    Function get_ToolBar() As HRESULT 
    Function put_ToolBar() As HRESULT 
    Function get_MenuBar() As HRESULT 
    Function put_MenuBar() As HRESULT 
    Function get_FullScreen() As HRESULT 
    Function put_FullScreen() As HRESULT 

End Interface 

Interface IWebBrowser2 
    Inherits IWebBrowserApp 

    Function Navigate2(URL As VoidPtr,Flags As VoidPtr,TargetFrameName As VoidPtr,PostData As VoidPtr,Headers As VoidPtr) As HRESULT 
    Function QueryStatusWB() As HRESULT 
    Function ExecWB() As HRESULT 
    Function ShowBrowserBar() As HRESULT 
    Function ReadyState() As HRESULT 
    Function get_Offline() As HRESULT 
    Function put_Offline() As HRESULT 
    Function get_Silent() As HRESULT 
    Function put_Silent() As HRESULT 
    Function get_RegisterAsBrowser() As HRESULT 
    Function put_RegisterAsBrowser() As HRESULT 
    Function get_RegisterAsDropTarget() As HRESULT 
    Function put_RegisterAsDropTarget() As HRESULT 
    Function get_TheaterMode() As HRESULT 
    Function put_TheaterMode() As HRESULT 
    Function get_AddressBar() As HRESULT 
    Function put_AddressBar() As HRESULT 
    Function get_Resizable() As HRESULT 
    Function put_Resizable() As HRESULT 

End Interface 

Interface IOleWindow 
    Inherits IUnknown 

    Function GetWindow(phwnd As *HWND) As HRESULT 
    Function ContextSensitiveHelp(fEnterMode As Long) As HRESULT 

End Interface 

Interface IOleInPlaceActiveObject 
    Inherits IOleWindow 

    Function TranslateAccelerator(lpmsg As *MSG) As HRESULT 
    Function OnFrameWindowActivate(fActivate As Long) As HRESULT 
    Function OnDocWindowActivate(fActivate As Long) As HRESULT 
    Function ResizeBorder(prcBorder As *RECT,pUIWindow As VoidPtr,fFrameWindow As Long) As HRESULT 
    Function EnableModeless(fEnable As Long) As HRESULT 

End Interface 

Declare Function AtlAxWinInit Lib "atl.dll" () As HRESULT
Declare Function AtlAxGetControl Lib "atl.dll" (hWnd As HWND,pp As VoidPtr) As HRESULT

次に MainWnd.sbp を大幅に書き替えます。
AtlAxWinInit の宣言の削除、必要なインターフェイスの取得と解放を行っています。
また TestProject_DestroyObjects の部分は「(プロジェクト名)_DestroyObjects」に書き替えます。

[ここをクリックすると内容が表示されます]

コード: 全て選択

'-----------------------------------------------------------------------------
'  イベント プロシージャ
'-----------------------------------------------------------------------------
' このファイルには、ウィンドウ [MainWnd] に関するイベントをコーディングします。
' ウィンドウ ハンドル: hMainWnd

' TODO: この位置にグローバルな変数、構造体、定数、関数を定義します。

Dim hBrowserWnd As HWND
Dim pUnknown As *IUnknown
Dim pWebBrowser2 As *IWebBrowser2
Dim pOleInPlaceActiveObject As *IOleInPlaceActiveObject

'-----------------------------------------------------------------------------
' ウィンドウメッセージを処理するためのコールバック関数

Function MainWndProc(hWnd As HWND, dwMsg As DWord, wParam As DWord, lParam As DWord) As DWord
    ' TODO: この位置にウィンドウメッセージを処理するためのコードを記述します。

    ' イベントプロシージャの呼び出しを行います。
    MainWndProc=EventCall_MainWnd(hWnd,dwMsg,wParam,lParam)
End Function

'-----------------------------------------------------------------------------
' ここから下は、イベントプロシージャを記述するための領域になります。

Sub MainWnd_Destroy()
	TestWindowsApplication_DestroyObjects()
	PostQuitMessage(0)
End Sub

Sub MainWnd_Create(ByRef CreateStruct As CREATESTRUCT)

    AtlAxWinInit()
    hBrowserWnd=CreateWindowEx(NULL,"AtlAxWin","http://www.yahoo.co.jp/",
    WS_CHILD Or WS_VISIBLE Or WS_VSCROLL Or WS_HSCROLL,
    0,0,100,100,hMainWnd,0,GetModuleHandle(NULL),NULL)
	AtlAxGetControl(hBrowserWnd,VarPtr(pUnknown))
	Dim IID_IWebBrowser2=[&HD30C1661,&HCDAF,&H11D0,[&H8A,&H3E,&H00,&HC0,&H4F,&HC9,&HE2,&H6E]] As GUID
	pUnknown->QueryInterface(VarPtr(IID_IWebBrowser2),VarPtr(pWebBrowser2))
	Dim IID_IOleInPlaceActiveObject=[&H00000117,&H0000,&H0000,[&HC0,&H00,&H00,&H00,&H00,&H00,&H00,&H46]] As GUID
	pWebBrowser2->QueryInterface(VarPtr(IID_IOleInPlaceActiveObject),VarPtr(pOleInPlaceActiveObject))
	pWebBrowser2->Release()
	pUnknown->Release()

End Sub

Sub MainWnd_Resize(SizeType As Long, cx As Integer, cy As Integer)

    MoveWindow(hBrowserWnd,0,0,cx,cy,TRUE)

End Sub

Sub MainWnd_QueryClose(ByRef cancel As Integer)

	pOleInPlaceActiveObject->Release()

End Sub

更に IE コンポーネントに処理を渡す為に、メッセージループを書き替えます。

[ここをクリックすると内容が表示されます]

コード: 全て選択

Dim Message As MSG
Do
	If GetMessage(Message,NULL,NULL,NULL)<>1 Then Exit Do
	If pOleInPlaceActiveObject->TranslateAccelerator(VarPtr(Message))=S_OK Then Continue
	TranslateMessage(Message)
	DispatchMessage(Message)
Loop

API の TranslateAccelerator と同じような感じです。

これで Ctrl+A や Ctrl+F 等の、IE コンポーネントのショートカットキーが使えるようになります。

見ていて思ったのですが，そのコードではIWebBrower2インタフェースは使っていないので，IUnknownへのポインタから直接IOleInPlaceActiveObjectをQueryInterfaceして構わないはずです。

もちろん後で使うためにIWebBrower2へのポインタを取っておくという方法も考えられますけどね。

Toshi様、ありがとう御座います。

　実践コードモジュールの「IE コンポーネントを表示してみる」に追加。

　Ver4.24で全選択（CTRL+Ａ）が出来る様に成りました。（凄いですね＾_＾）
（私は、未だにVer3.13を使用しているのですが、Ver3.13では無理でしょうか？）

【メモ】 [ここをクリックすると内容が表示されます]

ですが、今作成しているのはメイン画面ではなくダイアログボックスに
ブラウザウィンドウを２つ表示しているのですが、頂いたコードを追加し
Dim hBrowserWnd[1] As HWND
Dim pUnknown[1] As *IUnknown
Dim pWebBrowser2[1] As *IWebBrowser2
Dim pOleInPlaceActiveObject[1] As *IOleInPlaceActiveObject
等の様に変更しましたが有効なショートカットキー等、使用出来ません。
AtlAxGetControl()以降のコードは、Create時のみ有効のなのでしょうか？

　前後に成りましたが、イグトランス (egtra)様、何時もありがとう御座います。

宜しくお願いします。

AtlAxGetControl()以降のコードは、Create時のみ有効のなのでしょうか？

　　　　これは、問題では無いみたいですね。

　モーダルダイアログボックスの場合、メッセージループは”Callback.wbp”のDialogBox（）中に
在るのでここに追加したのですがコードを変更する度、書き換えなければならないので
他に方法は無いでしょうか？

　それと、ブラウザウィンドウのハンドルをWindowFromPoint（）で取得しているのですが、
他に取得する方法は無いでしょうか？

　ボタンをクリックして一連の作業をする場合、ブラウザウィンドウをクリックしてからでないと
出来ないのと一度アクティブ（？）に成るとフォーカスがエディットボックスに成っていても関係なく
Ctrl+A でブラウザウィンドウに対して全選択に成ってしまいますし、カーソルキーを押した場合も
ブラウザウィンドウの画面がスクロールしてしまいます。（SetFocus()は効きません）

　ブラウザウィンドウを２つ表示しているの場合、どちらに対して指定しているかの判別は、
度の様にすれば良いのでしょうか？

一度に沢山質問しましたが宜しくお願いします。

（私は、未だにVer3.13を使用しているのですが、Ver3.13では無理でしょうか？）

Ver. 3.13 は COM を扱えないので無理です。

Ver5.xxでは、エラー：「"VarPtr" 無効な識別子です」と成ります。

これは QueryInterface の引数の型が変わった為で、VarPtr() を外すだけでいいはずです。

コード: 全て選択

    pUnknown->QueryInterface(IID_IOleInPlaceActiveObject,pOleInPlaceActiveObject)

モーダルダイアログボックスの場合、メッセージループは”Callback.wbp”のDialogBox（）中に
在るのでここに追加したのですがコードを変更する度、書き換えなければならないので
他に方法は無いでしょうか？

フックを利用すると可能です。こちらのページの手法を参考にしてみてください。

それと、ブラウザウィンドウのハンドルをWindowFromPoint（）で取得しているのですが、
他に取得する方法は無いでしょうか？

CreateWindowEx が返したハンドルから子ウィンドウを辿っていき、
クラス名が "Internet Explorer_Server" のウィンドウを見つけるという方法がありますが、面倒です。

ブラウザウィンドウを２つ表示しているの場合、どちらに対して指定しているかの判別は、
度の様にすれば良いのでしょうか？

フックによってメッセージを捕まえたら GetFocus でフォーカスのあるハンドルを取得し、
あらかじめ取得しておいた、上記のウィンドウのハンドル 2 つとそれぞれ比較することで出来ます。
そして一致していた方の pOleInPlaceActiveObject->TranslateAccelerator を呼びます。

Toshi様、ありがとう御座います。

Ver. 3.13 は COM を扱えないので無理です。

　COM を使わず出来ないものかと思って。
と云うのも、例えば下記の様にすればメモ帳の全選択（CTRL+Ａ）が出来る様に、
ブラウザウィンドウに対しても出来ないのかなと思ったのです。
hWnd=FindWindow("Notepad", NULL)
PostMessage(hWnd, WM_COMMAND, 25, 0) ’２５はメニュのＩＤ

QueryInterface の引数の型が変わった為で、VarPtr() を外すだけでいいはずです。

　Ver5.xxから仕様が変わったのでしたね。（すみません）

　フックの事は過去に何度も教えて頂いたのですが、気が付きませんでした。
ブラウザウィンドウが複数表示してる場合も、どれを指定したか判別が出来る様に成りました。
　しかし、SetFocus（）で設定した場合、カーソルキー等で画面はスクロールしますが
ショートカットキー等は、ブラウザウィンドウをクリックしてからでないと使用出来ません。

　”Internet Explorer_Server”（クラス名）のハンドルは未だ取得できず、試行錯誤しています。
先ずCreateWindowEx（）で ”AtlAxWin”（クラス名）のウィンドウを生成し表示すると
次に”Shell DocObject View”（クラス名）のウィンドウが表示し
続いて”Internet Explorer_Server”のウィンドウが表示しますが、
このウィンドウが表示した事が解る関数は無いのでしょうか？
どのタイミングで又、何処でハンドルを取得すれば良いのでしょうか？

宜しくお願いします。

AtlAxGetControlして得たブラウザコントロールへのポインタからIOleWindowインタフェースを得られないでしょうか？

コード: 全て選択

Interface IOleWindow
    Inherits IUnknown

    Function GetWindow(ByRef hwnd As HWND) As HRESULT
    Function ContextSensitiveHelp(fEnterMode As BOOL) As HRESULT
End Interface

Dim IID_IOleWindow = [&h00000114, &h0000, &h0000, [&hC0, &h00, &h00, &h00, &h00, &h00, &h00, &h46]] As IID

コード: 全て選択

Dim pOleWindow As *IOleWindow
p->QueryInterface(IID_IOleWindow, pOleWindow) 'pはAtlAxGetControlで得たポインタか、それからQueryInterfaceして得たポインタ
Dim hwnd As HWND
pOleWindow->GetWindow(hwnd)
pOleWindow->Release()

おそらく IE コンポーネントはメモ帳のようなことは出来ません。（確証は無いですが）
また TranslateAccelerator を呼ばない限りショートカットキーを処理しないらしく、
それを自前でやる（プログラム側でキーボードイベントを捕まえて、それに対応する処理を IE コンポーネントに依頼する）
のにも COM が必要になってしまいます...。

しかし、SetFocus（）で設定した場合、カーソルキー等で画面はスクロールしますが
ショートカットキー等は、ブラウザウィンドウをクリックしてからでないと使用出来ません。

SetFocus は Internet Explorer_Server クラスのウィンドウにする必要があります。
このウィンドウが確実に存在するのなら、次の関数に hBrowserWnd を渡すとハンドルを取得出来ます。

コード: 全て選択

Function GetIEHWND(hParent As HWND) As HWND
	Dim hWnd As HWND
	Dim szClassName[255] As Byte
	hWnd=GetWindow(hParent,GW_CHILD)
	If hWnd Then
		GetClassName(hWnd,szClassName,255)
		If lstrcmp(szClassName,"Internet Explorer_Server")=0 Then
			GetIEHWND=hWnd
			Exit Function
		Else
			GetIEHWND=GetIEHWND(hWnd)
			Exit Function
		End If
	End If
	GetIEHWND=NULL
End Function

そして確実に存在することを確かめるにはまた COM を使って色々しなければならないので、
少し無理矢理ですがタイマーなどである程度の時間を待って、戻り値が NULL ではなくなるまで上の関数を呼ぶといった方法があります。

追記:
かぶってしまいました。

イグトランス (egtra)様、ありがとう御座います。

Sub MainWnd_Create(ByRef CreateStruct As CREATESTRUCT)

AtlAxWinInit()
hBrowserWnd=CreateWindowEx(NULL,"AtlAxWin","http://www.yahoo.co.jp/",
WS_CHILD Or WS_VISIBLE Or WS_VSCROLL Or WS_HSCROLL,
0,0,100,100,hMainWnd,0,GetModuleHandle(NULL),NULL)
AtlAxGetControl(hBrowserWnd,VarPtr(pUnknown))
Dim IID_IWebBrowser2=[&HD30C1661,&HCDAF,&H11D0,[&H8A,&H3E,&H00,&HC0,&H4F,&HC9,&HE2,&H6E]] As GUID
pUnknown->QueryInterface(VarPtr(IID_IWebBrowser2),VarPtr(pWebBrowser2))
Dim IID_IOleInPlaceActiveObject=[&H00000117,&H0000,&H0000,[&HC0,&H00,&H00,&H00,&H00,&H00,&H00,&H46]] As GUID
pWebBrowser2->QueryInterface(VarPtr(IID_IOleInPlaceActiveObject),VarPtr(pOleInPlaceActiveObject))

pWebBrowser2->QueryInterface(VarPtr(IID_IOleWindow), VarPtr(pOleWindow)) 'pはAtlAxGetControlで得たポインタか、それからQueryInterfaceして得たポインタ
Dim hwnd As HWND
pOleWindow->GetWindow((VarPtr(hwnd))
pOleWindow->Release()

pWebBrowser2->Release()
pUnknown->Release()

End Sub

　何処に入れれば良いのか解らないので取り合えず上記の様にしましたが
Internet Explorer_Server クラスのウィンドウハンドルは取得出来ませんでした。
pのポインタ変数はこれで良いのでしょうか？

　Interface中の各Function の機能の解説があるサイトがあれば教えてください。
Refresh（）で”更新”出来る等便利で他にも使いたいのですが機能名だけからでは
解らないものが多いので。

宜しくお願いします。

Toshi様、ありがとう御座います。

おそらく IE コンポーネントはメモ帳のようなことは出来ません。（確証は無いですが）
また TranslateAccelerator を呼ばない限りショートカットキーを処理しないらしく、
それを自前でやる（プログラム側でキーボードイベントを捕まえて、それに対応する処理を IE コンポーネントに依頼する）
のにも COM が必要になってしまいます...。

　IE コンポーネント等はCOM が不可欠なんですね。
色々調べて頂いてありがとう。

SetFocus は Internet Explorer_Server クラスのウィンドウにする必要があります。

　SetFocus で指定したウィンドウハンドルは、Internet Explorer_Server クラスのウィンドウです。
GetIEHWNDで得たハンドルですよね。

今迄、WindowFromPoint で取得していましたがGetIEHWNDを使わして頂きます。(^_^)

　そして確実に存在することを確かめるにはまた COM を使って色々しなければならないので、
少し無理矢理ですがタイマーなどである程度の時間を待って、戻り値が NULL ではなくなるまで上の関数を呼ぶといった方法があります。

　「COM を使用すれば存在することを確かめられる」のが、イグトランス (egtra)様のコードでしょうか？
何処に入れれば良いのか使い方が解ずお聞きしているところです。

　ウィンドウが表示した事が解る関数は無いみたいで、COM で出来ない場合はタイマーを使って取得するしか無いみたいですね。

宜しくお願いします。

はい，そういうコードを想定していました。お役に立てず済みません。

ちなみに，そのコードはここを参考にしました。
Obtaining the HWND for the WebBrowser control - Microsoft Support Online

イグトランス (egtra)様、ありがとう御座います。

はい，そういうコードを想定していました。お役に立てず済みません。

　いいえ、何時も役に立つ回答を頂いています！(^_^)

　現在は、Toshi様が提案して頂いたタイマーを使ってGetIEHWNDでハンドルを取得していますが、
Internet Explorer_Server クラスのウィンドウが表示した事が解る関数が有れば教えてください。

　フォーカスなのですが、ブラウザウィンドウをクリックしてからでないとショートカットキー等は
使用出来無い為、SetCursorPosでマウスカーソルをブラウザウィンドウに移動しmouse_eventで
クリックしてますが、他に方法は無いでしょうか？
SetFocusだけでは駄目なので、AttachThreadInputを試したのですが上手くいきません。

　それと、ブラウザウィンドウ中のＴＡＢによるフォーカス移動が出来ないのですが、度の様にすれば
良いのでしょうか？

【おまけ】 [ここをクリックすると内容が表示されます]

宜しくお願いします。

ab.com コミュニティ

IEコンポーネント上の全選択方法

IEコンポーネント上の全選択方法

IEコンポーネント上の全選択方法

IEコンポーネント上の全選択方法

IEコンポーネント上の全選択方法

IEコンポーネント上の全選択方法

IEコンポーネント上の全選択方法

IEコンポーネント上の全選択方法