ab.com コミュニティ

コード: 全て選択

Dim hMem As HGLOBAL
Dim lpStr As LPSTR

' ヒープ領域から256バイト分メモリを確保
hMem=GlobalAlloc(GMEM_DDESHARE or GHND,256)
If hMem Then
	' メモリブロックの先頭ポインタを取得
	lpStr=GlobalLock(hMem)
	If lpStr Then
		'----------変数lpStrに対しメモリの操作を行う----------
		'----------ここまで----------
		GlobalUnlock(hMem)
		If OpenClipboard(hMainWnd) Then
			EmptyClipboard()
			' 文字列をクリップボードに設定
			SetClipboardData(CF_TEXT,hMem)
			CloseClipboard()
		End If
	Else
		GlobalFree(hMem)
	End If
End If

コード: 全て選択

Function SetClipboardText(ByVal hWndNewOwner As HWND,ByVal lpszStr As LPCSTR) As BOOL
Dim hMem As HGLOBAL
Dim lpStr As LPSTR

	hMem=GlobalAlloc(GMEM_DDESHARE Or GHND,lstrlen(lpszStr)+1)
	If hMem Then
		lpStr=GlobalLock(hMem)
		If lpStr Then
			lstrcpy(lpStr,lpszStr)
			GlobalUnlock(hMem)
			If OpenClipboard(hWndNewOwner) Then
				EmptyClipboard()
				SetClipboardData(CF_TEXT,hMem)
				CloseClipboard()
				Return TRUE
			End If
		Else
			GlobalFree(hMem)
		End If
	End If
	Return FALSE
End Function

Function GetClipboardText(ByVal hWndNewOwner As HWND,ByRef lpStr As LPSTR) As BOOL
Dim hMem As HGLOBAL
Dim lpString As LPSTR

	If OpenClipboard(hWndNewOwner) Then
		hMem=GetClipboardData(CF_TEXT)
		CloseClipboard()
		If hMem Then
			lpString=GlobalLock(hMem)
			lpStr=calloc(lstrlen(lpString)+1)
			lstrcpy(lpStr,lpString)
			GlobalUnlock(hMem)
			Return TRUE
		End If
	'	CloseClipboard()
	End If
	Return FALSE
End Function

'------------------------------------------------------------
' ファイルのコピー
'------------------------------------------------------------
' 変数FileNameにファイルの絶対パスを格納する
Dim FileName[MAX_PATH-1] As Byte

	' ファイルのコピーを行う。(ファイルの絶対パスをクリップボードに格納)
	' メモ帳に貼り付けしてもファイルパスがペーストされるので
	' RegisterClipboardFormat()関数で
	' 独自のクリップボードフォーマットを作って
	' そこに格納させた方が良い？
	SetClipboardText(hMainWnd,FileName)

'------------------------------------------------------------
' ファイルのペースト
'------------------------------------------------------------
Dim lpStr As LPSTR
	GetClipboardText(hMainWnd,lpStr)

	' 同名ファイルが存在する場合、関数は失敗
	CopyFile(lpStr,/* コピー先ファイルの絶対パス */,TRUE)

コード: 全て選択

Type DROPFILES
	pFiles As DWord
	pt As POINTAPI
	fNC As BOOL
	fWid As BOOL
End Type

Dim df As DROPFILES
Dim FileName[MAX_PATH-1] As Byte
Dim hMem As HGLOBAL
Dim lpVoid As VoidPtr

	lstrcpy(FileName,/* ファイルの絶対パス */)

	df.pFiles=SizeOf(DROPFILES)
	df.pt.x=0
	df.pt.y=0
	df.fNC=FALSE
	df.fWid=TRUE

	hMem=GlobalAlloc(GHND,df.pFiles+lstrlen(FileName)+1)
	lpVoid=GlobalLock(hMem)

	memcpy(lpVoid,VarPtr(df),df.pFiles)
	memcpy(lpVoid+df.pFiles,FileName,lstrlen(FileName))

	GlobalUnlock(hMem)

	If OpenClipboard(hMainWnd) Then
		EmptyClipboard()
		SetClipboardData(CF_HDROP,hMem)
		CloseClipboard()
	End If

コード: 全て選択

' 変数FileNameにファイルの絶対パスを格納する
Dim FileName[MAX_PATH-1] As Byte

Dim df As *DROPFILES
Dim hMem As HGLOBAL
Dim p As LPSTR

	lstrcpy(FileName,/* ファイルの絶対パス */)

	hMem=GlobalAlloc(GHND,SizeOf(DROPFILES)+lstrlen(FileName)+2)
	p=GlobalLock(hMem)

	df=p As *DROPFILES

	df->pFiles=SizeOf(DROPFILES)
	df->pt.x=0
	df->pt.y=0
	df->fNC=TRUE
	df->fWid=FALSE

	p+=SizeOf(DROPFILES)
	lstrcpy(p,FileName)
	p+=lstrlen(p)+1

	lstrcpy(p,Chr$(0))

	GlobalUnlock(hMem)

	If OpenClipboard(hMainWnd) Then
		EmptyClipboard()
		SetClipboardData(CF_HDROP,hMem)
		CloseClipboard()
	End If